開發商品的交易系統 - 基礎篇 [37]

EasyTrader ArtNo 261

威廉變異離散量又稱WVAD指標，由Larry Williams所創。是一種將成交量加權的量價指標。
威廉變異離散量的主要的理論精髓，在於重視一天中開盤到收盤之間的價位，而將此區域之上的價位視為壓力，區域之下的價位視為支撐，求取此區域占當天總波動的百分比，以便測量當天的成交量中，有多少屬於此區域。成為實際有意義的交易量。
　如果區域之上的壓力較大，將促使WVAD變成負值，代表賣方的實力強大，此時應該賣出持股。如果區域之下的支撐較大，將促使WVAD變成正值，代表買方的實力雄厚，此時應該買進股票。
　WVAD正負之間，強弱一線之隔。非常符合我們推廣的東方哲學技術理論，由於模擬測試所選用的周期相當長,測試結果也以長周期成績較佳。因此，建議長期投資者適合使用，如同EMV使用法則一樣，應該在一定的投資期限內，不斷的根據WVAD訊號將交易買賣，以求得統計盈虧概率的成果。

威廉變異離散量的計算公式
1、A=當天收盤價－當天開盤價
2、B=當天最高價－當天最低價
3、V=當天成交金額
4、WVAD=∑(A÷B×V)
5、參數周期可更改為6或12天

威廉變異離散量的研判
1、當WVAD由負值變成正值的一剎那，視為長期的買入點。
2、當WVAD由正值變面負值的一剎那，視為長期的獲利點。

{系統參數與變數}
input:EntryType(1),ExitType(2);
inputs:NBarL(24),NBarS(12),TradeProfit(0.02),TradeStopLoss(0.035),ATRs_L(10.78),ATRs_S(6.4);
vars: IsBalanceDay(False),MP(0),PF(0),PL(0),HLRange(100);

inputs:Len1(2),Len2(12),LR(0.3),HR(0.7),HighBar(13),LowBar(15);
Vars: OC(0),HL(0),WVAD(0),Vol(0),BodyR(0) ;
Vars: HHWVAD(0),LLWVAD(0),GAP(0),HighBAnd(0),LowBand(0) ;;

MP = MarketPosition ;

if DAYofMonth(Date) > 14 and DAYofMonth(Date) < 22 and DAYofWeek(Date)= 3 then isBalanceDay = True else isBalanceDay =False ;

PF = AvgPrice*TradeProfit ;
PL = AvgPrice*TradeStopLoss ;

{計算 WVAD }
OC = Close-Open ;
HL = Range ;
Vol = iff(DataCompression > 1,Volume,Ticks) ; {計算日K/分K成交量 }

if HL <> 0 then BodyR = OC/HL ;
WVAD = Summation(BodyR*Vol,Len1) ;

{ 策略元素 2 - 高低通道}
HHWVAD = Highest(WVAD,Len2)[1] ;
LLWVAD = Lowest(WVAD,Len2)[1] ;
GAP = HHWVAD - LLWVAD ;
HighBand = LLWVAD + HR*GAP ;
LowBand = LLWVAD + LR*GAP ;

{ 策略元素 1 - 穿越零軸進場 }
if EntryType = 1 then Begin
if MP <> 1 and WVAD Cross over 0 then Buy next bar at Highest(High,HighBar) stop ;
if MP <> -1 and WVAD Cross under 0 then Sell next bar at Lowest(Low,LowBar) stop ;
end;

{ 策略元素 2 - 穿越高低通道進場 }
if EntryType = 2 then Begin
if MP <> 1 and WVAD Cross over HighBand then Buy next bar at Highest(High,HighBar) stop ;
if MP <> -1 and WVAD Cross under LowBand then Sell next bar at Lowest(Low,LowBar) stop ;
end;

{Exits}
if ExitType = 1 then SetStopLoss(PL * BigPointValue) ;

if ExitType = 2 then Begin
SetStopLoss(PL * BigPointValue) ;
setProfitTarget(PF * BigPointValue) ;
end;

if ExitType = 3 then Begin
if MP > 0 and BarsSinceEntry = NBarL then ExitLong next bar at Market ;
if MP < 0 and BarsSinceEntry = NBarS then ExitShort next bar at Market ;
end;

if ExitType = 4 then Begin
SetStopLoss(PL * BigPointValue) ;
setProfitTarget(PF * BigPointValue) ;
if MP > 0 and BarsSinceEntry = NBarL then {Sell } ExitLong next bar at Market ;
if MP < 0 and BarsSinceEntry = NBarS then {Buy} ExitShort next bar at Market ;
end;

if IsBalanceDay or date = 1150224 then setExitonClose ;
策略元素 1 台指期 60 min K 多空留倉 交易週期 2005/2/1~ 2015/1/31 交易成本 1200


策略元素 2 台指期 60 min K 多空留倉 交易週期 2005/2/1~ 2015/1/31 交易成本 1200

結論：策略元素 2是利用過去N根K棒所產生的 WVAD數值的高低點區間的某個比例值建立通道,以達到隨盤勢變化的自適應性的調整

MagicQS170