開發商品的交易系統 - 基礎篇 [18]

EasyTrader ArtNo 222

海龜交易法則的核心進出場元素-唐契安通道(Donchian Channels) 。唐契安通道是可以被應用​​到任何圖表技術工具。通過它們來識別在圖上的區間最高和最低的價格，在期間內所選擇的K棒數，用以找出的支撐和壓力的位置。在外匯市場是很常被應用的一個有效通道策略



設定風險與追踪止損
在任何交易策略，設定止損和管理風險應予以考慮。當使用唐契安頻道，這個過程可以被簡化。在一個上升趨勢，價格有望向更高的高點，並保持高於此值。如果價格通過底部通道的低點，我們就要退出所有的多頭部位。相反，在下跌趨勢，場中空方交易者就要在頂部通道止損平倉。
在台指期商品是否也能使用此通道來作為交易策略呢 ?一如以往先畫指標線觀察

inputs:RangeA(20);

Vars:RangeHigh(0),RangeLow(0);

RangeHigh = Highest(high,RangeA)[1] ;

RangeLow = Lowest(Low,RangeA)[1] ;

Plot1(RangeHigh,"RH",Magenta,Black,3) ;

Plot2(RangeLow,"RL",Cyan,Black,3) ;

測試程式碼
input:ExitType(2) ;
inputs:NBarL(2),NBarS(2),TradeProfit(0.025),TradeStopLoss(0.015),ATRs_L(5.4),ATRs_S(10.9);
vars: IsBalanceDay(False),MP(0),PF(0),PL(0);

inputs:LongLen(20),ShortLen(20),EntL(5),EntS(5);
Vars:RangeHigh(0),RangeLow(0);

MP = MarketPosition ;

if DAYofMonth(Date) > 14 and DAYofMonth(Date) < 22 and DAYofWeek(Date)= 3 then isBalanceDay = True else isBalanceDay =False ;

PF = AvgPrice*TradeProfit ;
PL = AvgPrice*TradeStopLoss ;

{ 計算前 N 根K棒的高低點 }
RangeHigh = Highest(high ,LongLen)[1] ;
RangeLow = Lowest(Low,LongLen)[1] ;

{ 進場作多邏輯 - 空倉時，收盤價突破前期高點後，且是近期高點作多 }
if MP = 0 and Close Cross over RangeHigh then Buy next bar at Highest(High,EntL) stop ;

{ 進場作空邏輯 - 空倉時，收盤價跌破前期低點後，且是近期低點作空 }
if MP = 0 and Close Cross under RangeLow then Sell next bar at Lowest(Low,EntS) stop ;

if ExitType = 1 then SetStopLoss(PL * BigPointValue) ;

if ExitType = 2 then Begin
SetStopLoss(PL * BigPointValue) ;
setProfitTarget(PF * BigPointValue) ;
end;

if ExitType = 3 then Begin
if MP > 0 and BarsSinceEntry = NBarL then ExitLong next bar at Market ;
if MP < 0 and BarsSinceEntry = NBarS then ExitShort next bar at Market ;
end;

if ExitType = 4 then Begin
SetStopLoss(PL * BigPointValue) ;
setProfitTarget(PF * BigPointValue) ;
if MP > 0 and BarsSinceEntry = NBarL then {Sell } ExitLong next bar at Market ;
if MP < 0 and BarsSinceEntry = NBarS then {Buy} ExitShort next bar at Market ;
end;

if IsBalanceDay then setExitonClose ;

台指期 30 分K 留倉 回測週期 2004/8/30~2014/8/29 交易成本 1200

還是有一定的績效水準!
在上面外匯圖上還有一個小暗示喔 , 如果將它當作濾網並將多空變數區分

讀者可以動手試試看找答案
結論：通常我們認為策略程式公佈後就很容易失效，而此篇的通道策略算是一個歷史悠久的進出邏輯，只要細心去觀察，即使它是一個舊元素一樣可以賦予新的生命。

MagicQS129