金融商品交易 觀盤篇 – 箱型指標(II)

EasyTrader - ArtNo 002

延續前篇

---- 6. NearDay High/Low (近日高低點) ----

input: Barlookback(5) ; { LookBack }
Vars: HighBand(0),LowBand(0);

if DataCompression < 2 then Begin
   HighBand = HighD(0) ;
   LowBand = LowD(0) ;

   for Value1 = 1 to BarlookBack Begin
       if HighD(Value1) > HighBand then HighBand = HighD(Value1) ;
       if LowD(Value1) < LowBand then LowBand = LowD(Value1) ;
   end;
end else Begin
   HighBand = High ;
   LowBand = Low ;

   for Value1 = 1 to BarlookBack Begin
       if High[Value1] > HighBand then HighBand = High[Value1] ;
       if Low[Value1] < LowBand then LowBand = Low[Value1] ;
   end;
end;

Plot1(HighBand , "NearDayHigh" ) ;
Plot2(LowBand , "NearDayLow" ) ;


程式碼說明

宣告參數 ( 參考日數 ,可作最佳化設定 )
宣告變數

If DataCompression …

   先定義變數為高低點值

   若後續迴圈內有新高/新低值則用以更新原變數內含值
End; 此段為自動判定是 分K 或是 日K以上 時間架構

For …Begin
.......

End 迴圈為計算近 N日高低點

畫線語法(數值,名稱,前景色,背景色,線條寬度)

Plot1(Value,”StrNmae”,Fgcolor,Bgcolor,Width)

最簡單用法 plot1(value) , 名稱主要是在作指標設定時辨識方便
可依需求設定觀察日數

---- 7. NearBar High/Low ( 指定K棒根數範圍內高低點) ----

input: Barlookback(5) ; { LookBack }
Vars: HighBand(0),LowBand(0);

HighBand = Highest(High,BarLookBack) ;
LowBand = Lowest(Low,BarLookBack) ;

Plot1(HighBand[1] , "NearBarHigh" ) ;
Plot2(LowBand[1], "NearBarLow" ) ; 

程式碼說明

宣告參數 ( 參考K棒數 ,可作最佳化設定 )
宣告變數

語法:

最近N 根K棒最高值 Highest(High,N)
最近N 根K棒最高值 Lowest(Low,N)

前一個最近N 根K棒最高值 Highest(High,N)[1]
前一個最近N 根K棒最高值 Lowest(Low,N)[1]

畫線語法(數值,名稱,前景色,背景色,線條寬度)
Plot1(Value,”StrNmae”,Fgcolor,Bgcolor,Width)

最簡單用法 plot1(value) , 名稱主要是在作指標設定時辨識方便

---- 8 Three Gate (三關價) ----

用在研判短線或當沖，可找出其區間和支撐壓力的判斷方式，也是交易者掌握盤勢的重要參考指標。

所謂三關價 指上關、中關及下關的價格，其次日的三關價計算公式是：

*上關：今低+（今高-今低）乘以 1.382
*中關：（今高+今低）／2
*下關：今高-（今高-今低）乘以 1.382。

Vars: UpGate(0), MedGate(0),DnGate(0);

if DataCompression < 2 then Begin
   UpGate = LowD(1)+(HighD(1)-LowD(1))*1.382 ;
   MedGate = (HighD(1)+LowD(1))/2 ;
   DnGate = HighD(1)-(HighD(1)-LowD(1))*1.382 ;
end else Begin
   UpGate = Low[1]+(High[1]-Low[1])*1.382 ;
   MedGate = (High[1]+Low[1])/2 ;
   DnGate = High[1]-(High[1]-Low[1])*1.382 ;
end;

Plot1(Upgate,"Upgate") ;
Plot2(MedGate,"MedGate") ;
Plot3(DnGate,"DnGate") ;

程式碼說明

宣告變數

今日的三關價所以取昨日的價格計算

If DataCompression …
   依公式計算上關 , 中關 , 下關
End; 此段為自動判定是 分K 或是 日K以上 時間架構

畫線語法(數值,名稱,前景色,背景色,線條寬度)
Plot1(Value,”StrNmae”,Fgcolor,Bgcolor,Width)

最簡單用法 plot1(value) , 名稱主要是在作指標設定時辨識方便



網路上許多三關價研判法則 ,不再贅述

---- 9. CDP (逆勢操作系統) ----

在技術指標上，CDP（逆勢操作系統），是利用前一個交易日的開盤價、收盤價、最高價與最低價的資訊，將其計算與分析，劃分當天價格變動範圍為五個等級，做為當日短線進出的研判標準。

公式：

Ｈ：最高價，L：最低價，O：開盤價，C：收盤價，波幅:（即最高價減最低價）

(1) 首先求出昨日行情的CDP值：

　　CDP = ( H + L + 2C ) / 4

(2) 再分別計算昨天行情得最高值(AH)、近高值(NH)、近低值(NL)及最低值(AL)：

　　AH = CDP +（H-L)

　　NH = 2CDP - L

　　NL = 2CDP – H

　　AL = CDP –（H-L)

Vars: CDP(0),AH(0),NH(0),NL(0),AL(0);

if DataCompression < 2 then Begin
   CDP = (HighD(1)+LowD(1)+CloseD(1)*2)/4 ;
   AH = CDP + (HighD(1)-LowD(1)) ;
   NH = CDP*2 - LowD(1) ;
   NL = CDP*2 - HighD(1) ;
   AL = CDP - (HighD(1)-LowD(1)) ;
end else Begin
   CDP = (High[1]+Low[1]+Close[1]*2)/4 ;
   AH = CDP + (High[1]-Low[1]) ;
   NH = CDP*2 - Low[1] ;
   NL = CDP*2 - High[1] ;
   AL = CDP - (High[1]-Low[1]) ;
end;

Plot1(AH,"AH") ;
Plot2(NH,"NH") ;
Plot3(NL,"NL") ;
Plot4(AL,"AL") ;

程式碼說明

宣告變數

If DataCompression …
   依公式計算 CDP、 最高值(AH)、近高值(NH)、近低值(NL)及最低值(AL)
End; 此段為自動判定是 分K 或是 日K以上 時間架構

畫線語法(數值,名稱,前景色,背景色,線條寬度)
Plot1(Value,”StrNmae”,Fgcolor,Bgcolor,Width)

最簡單用法 plot1(value) , 名稱主要是在作指標設定時辨識方便



網路上許多 CDP應用法則 ,不再贅述