台指期全時段交易回測篇 [41]

EasyTrader TestNo 041

ADX 是一個獨特的指標，用來顯示當前趨勢強度，那就是說如果市場是在趨勢中，它顯示的是強度。但是ADX 指標無法表示趨勢是向上或向下的，事實上，我們需考慮的是 ADX 本身移動的方向。
當市場由趨勢性轉為非趨勢性的期間，通常伴隨著的特點是 ADX 的下降或是較低的ADX值。這些非趨勢期間的時期被稱為市場橫盤、 糾結或整合時期，這通常是下一波趨勢開始前的準備階段。當ADX的指標值愈來愈增加時，這意味著目前的趨勢開始轉強。

Williams %R是由在世界交易競賽中贏得優秀、創下輝煌戰績的知名投資者Larry R. Williams所開發的技術指標。震盪指標的概要主要是為了掌握「以一定期間的最高價與最低價的範圍為基準，掌握最近的收盤價相對處於何種水平」。

// Public Variable
vars:MP(0),PF(0),PL(0),DayLast(1345),NightLast(0500),BuyPrice(0),ShortPrice(0),BasePF(150),BasePL(100),FilterA(0),FilterB(0) ;
vars:BarPass(5),HLRange(0),WinPoint(0),HBarPos(0),LBarPos(0),ExitH(0),ExitL(0),TimeOK(false),EntryExitCond(false),SelectNo(0) ;
vars:jumpPoint(0) ;
jumpPoint = MinMove/PriceScale ;

//****************** Basic Setup ****************************************

MP = MarketPosition ;

if MP <> 0 then Begin

   PF = EntryPrice*TradeProfit ;

   PL = EntryPrice*TradeStopLoss ;

end else begin

   PF = AvgPrice*TradeProfit ;

   PL = AvgPrice*TradeStopLoss ;

end ;

if Close > 10000 then begin

   BasePF = BasePF+IntPortion((Close-10000)/1000)*30 ;

   BasePF = MinList(BasePF,450*jumpPoint) ;

   BasePL = BasePL+IntPortion((Close-10000)/1000)*15 ;

   BasePL = MinList(BasePL,225*jumpPoint) ;

end ;

PF = MinList(PF,BasePF) ;

PL = MinList(PL,BasePL) ;

PF = MinList(PF,450*jumpPoint) ;

PL = MinList(PL,225*jumpPoint) ;

//計算自訂義MACD價格

// ************ Macd *****************

vars:uDif(0),uMacd(0),uOsc(0),MacdLen(0) ;

MacdLen = MaxList(LenA1,LenB1) ;

if MacdLen > 12 then MacdLen = 12 ;

uDif = Macd((High+Low+Close*2)/4,IntPortion(MacdLen*1.3),MacdLen*3) ;

uMacd = Xaverage(uDif,MacdLen) ;

uOsc = uDif-uMacd ;

//計算近三月區間價格

// ************3 Month High or Low *****************

vars:MonthH(High),MonthL(Low),MonthHL(0),MonthHPB(0),MonthLPB(0),Month33(0),Month67(0) ;

MonthH = MaxList(HighM(0),HighM(1),HighM(2)) ;

MonthL = MinList(LowM(0),LowM(1),LowM(2)) ;

MonthHL = MonthH - MonthL ;

Month33 = MonthL+MonthHL*0.33 ;

Month67 = MonthL+MonthHL*0.67 ;

MonthHPB = _BarsLast(High = MonthH) ;

MonthLPB = _BarsLast(Low = MonthL) ;

//計算近60根K棒區間價格

// ************Fix Length High or Low *****************

vars:FixLenH(High),FixLenL(Low),FixLenHL(0),FixLenHPB(0),FixLenLPB(0),FixLen33(0),FixLen67(0) ;

FixLenH = Highest(High,60) ;

FixLenL = Lowest(Low,60) ;

FixLenHL = FixLenH - FixLenL ;

FixLen33 = FixLenL+FixLenHL*0.33 ;

FixLen67 = FixLenL+FixLenHL*0.67 ;

FixLenHPB = _BarsLast(High = FixLenH) ;

FixLenLPB = _BarsLast(Low = FixLenL) ;

// ************* Time Set Up *************

TimeOK = ((time >= 0900 and time <= 1200) or (time >= 2130) or time <= 0300) ;

//***************** BuyPrice & ShortPrice Setup *****************

if BuyMode = 20 then BuyPrice = Maxlist(HighD(0),HighD(1),HighD(2))-Range*0.5 ;

if ShortMode = 26 then ShortPrice = HighD(0)+OpenD(0)*RatioS/10000  ;

// ********** Main Strategy *********

// ********** Entry Method

//計算威廉指標及 ADX 指標

// ******** William PercentR Entry ***********

vars:PR1(0),vADX1(0),PR2(0),vADX2(0) ;

PR1 = PercentR(LenA1);

vADX1 = ADX(LenB1);

PR2 = PercentR(LenA2);

vADX2 = ADX(LenB2);

   if TimeOK then begin

// ADX值大於特定值 且威廉指標大於目標值 則收盤價突破設定價位做多

      if MP <> 1 and vADX1 > NBarL and PR1 > HighBand and Close < BuyPrice then 

         Buy ("LE_PcentRT") next bar at BuyPrice stop;

// ADX值大於特定值 且威廉指標大於目標值 則收盤價跌破設定價位做空

      if MP <> -1 and vADX2 > NBarS and PR2 < LowBand and Close > ShortPrice then 

         Sellshort ("SE_PcentRT") next bar at ShortPrice stop;

   end ;

   if TimeOK then begin

//近月高點拉回後 再達近月高點且 近期低點皆大於近月低點 市價做多

    if MP <> 1 and MonthHPB[1] > LenA1 and MonthHPB = 0 and Lowest(Low,LenA1) > MonthL then  buy ("LE_MonthHPBT") next bar at Market ;

//近月低點反彈後 再達近月低點且 近期高點皆小於近月高點 市價做空

    if MP <> -1 and MonthLPB[1] > LenB1 and MonthLPB = 0 and Highest(High,LenB1) < MonthH  then  sellshort ("SE_MonthLPBT") next bar at Market ;

   end ;

//基本停利+移動停損出場

// ************* Base Exit *************

if MP > 0 then Sell ("Trail_PL2_"+NumtoStr(Absvalue(EntryPrice-(HighSinceEntry-MinList((PL+PF)*0.5,PL))),0)) 

   All Contracts next bar at HighSinceEntry-MinList((PL+PF)*0.5,PL) stop ;   

if MP > 0 then Sell ("LPF1_"+NumtoStr(PF,0)) All Contracts next bar at EntryPrice+PF limit ;

if MP < 0 then BuytoCover ("Trail_SL2_"+NumtoStr(Absvalue(EntryPrice-(LowSinceEntry+MinList((PL+PF)*0.5,PL))),0)) 

   All Contracts next bar at LowSinceEntry+MinList((PL+PF)*0.5,PL) stop ;

if MP < 0 then BuytoCover ("SPF1_"+NumtoStr(PF,0)) All Contracts next bar at EntryPrice-PF limit ;

//空單部位獲利不如預期 反手做多

   if MP < 0 and (BarsSinceEntry >= 300/Barinterval and MaxPositionprofit/currentcontracts < 5000) 

      then Buy ("WrongEntryS5") next bar at Close stop ;

// 持有空單 且 MACD柱狀圖向上 且突破60根K區間價2/3 平倉出場

   if MP < 0 and uOsc > uOsc[1] and uOsc > RatioL-10 and Close < FixLen67 then 

      buytocover ("SX_UOsc1") next bar at FixLen67 stop ;

// 持有多單 且 MACD柱狀圖向下 且跌破60根K區間價1/3 平倉出場

   if MP > 0 and uOsc < uOsc[1] and uOsc < RatioS-10 and Close > FixLen33 then 

      sell ("LX_UOsc1") next bar at FixLen33 stop ;

//結算日出場

if _IsSettlementDay and time >= CalcTime(1300,-1*BarInterVal) and Time <= 1330 then begin

   if MP > 0 then Sell ("LX_Bal") next bar at market ;

   if MP < 0 then BuyToCover ("SX_Bal") next bar at market ;

end;

台指期 留倉 交易週期 2018/1/1 ~ 2023/12/31 交易成本 1200